lib/ZOOM.pm

   1 # $Id: ZOOM.pm,v 1.33 2006-04-12 12:00:48 mike Exp $
   2
   3 use strict;
   4 use warnings;
   5 use Net::Z3950::ZOOM;
   6
   7
   8 package ZOOM;
   9
  10 # Member naming convention: hash-element names which begin with an
  11 # underscore represent underlying ZOOM-C object descriptors; those
  12 # which lack them represent Perl's ZOOM objects.  (The same convention
  13 # is used in naming local variables where appropriate.)
  14 #
  15 # So, for example, the ZOOM::Connection class has an {_conn} element,
  16 # which is a pointer to the ZOOM-C Connection object; but the
  17 # ZOOM::ResultSet class has a {conn} element, which is a reference to
  18 # the Perl-level Connection object by which it was created.  (It may
  19 # be that we find we have no need for these references, but for now
  20 # they are retained.)
  21 #
  22 # To get at the underlying ZOOM-C connection object of a result-set
  23 # (if you ever needed to do such a thing, which you probably don't)
  24 # you'd use $rs->{conn}->_conn().
  25
  26 # ----------------------------------------------------------------------------
  27
  28 # The "Error" package contains constants returned as error-codes.
  29 package ZOOM::Error;
  30 sub NONE { Net::Z3950::ZOOM::ERROR_NONE }
  31 sub CONNECT { Net::Z3950::ZOOM::ERROR_CONNECT }
  32 sub MEMORY { Net::Z3950::ZOOM::ERROR_MEMORY }
  33 sub ENCODE { Net::Z3950::ZOOM::ERROR_ENCODE }
  34 sub DECODE { Net::Z3950::ZOOM::ERROR_DECODE }
  35 sub CONNECTION_LOST { Net::Z3950::ZOOM::ERROR_CONNECTION_LOST }
  36 sub INIT { Net::Z3950::ZOOM::ERROR_INIT }
  37 sub INTERNAL { Net::Z3950::ZOOM::ERROR_INTERNAL }
  38 sub TIMEOUT { Net::Z3950::ZOOM::ERROR_TIMEOUT }
  39 sub UNSUPPORTED_PROTOCOL { Net::Z3950::ZOOM::ERROR_UNSUPPORTED_PROTOCOL }
  40 sub UNSUPPORTED_QUERY { Net::Z3950::ZOOM::ERROR_UNSUPPORTED_QUERY }
  41 sub INVALID_QUERY { Net::Z3950::ZOOM::ERROR_INVALID_QUERY }
  42 sub CQL_PARSE { Net::Z3950::ZOOM::ERROR_CQL_PARSE }
  43 sub CQL_TRANSFORM { Net::Z3950::ZOOM::ERROR_CQL_TRANSFORM }
  44 # The following are added specifically for this OO interface
  45 sub CREATE_QUERY { 20001 }
  46 sub QUERY_CQL { 20002 }
  47 sub QUERY_PQF { 20003 }
  48 sub SORTBY { 20004 }
  49 sub CLONE { 20005 }
  50 sub PACKAGE { 20006 }
  51 sub SCANTERM { 20007 }
  52 sub LOGLEVEL { 20008 }
  53
  54 # The "Event" package contains constants returned by last_event()
  55 package ZOOM::Event;
  56 sub NONE { Net::Z3950::ZOOM::EVENT_NONE }
  57 sub CONNECT { Net::Z3950::ZOOM::EVENT_CONNECT }
  58 sub SEND_DATA { Net::Z3950::ZOOM::EVENT_SEND_DATA }
  59 sub RECV_DATA { Net::Z3950::ZOOM::EVENT_RECV_DATA }
  60 sub TIMEOUT { Net::Z3950::ZOOM::EVENT_TIMEOUT }
  61 sub UNKNOWN { Net::Z3950::ZOOM::EVENT_UNKNOWN }
  62 sub SEND_APDU { Net::Z3950::ZOOM::EVENT_SEND_APDU }
  63 sub RECV_APDU { Net::Z3950::ZOOM::EVENT_RECV_APDU }
  64 sub RECV_RECORD { Net::Z3950::ZOOM::EVENT_RECV_RECORD }
  65 sub RECV_SEARCH { Net::Z3950::ZOOM::EVENT_RECV_SEARCH }
  66 sub ZEND { Net::Z3950::ZOOM::EVENT_END }
  67
  68 # ----------------------------------------------------------------------------
  69
  70 package ZOOM;
  71
  72 sub diag_str {
  73     my($code) = @_;
  74
  75     # Special cases for error specific to the OO layer
  76     if ($code == ZOOM::Error::CREATE_QUERY) {
  77         return "can't create query object";
  78     } elsif ($code == ZOOM::Error::QUERY_CQL) {
  79         return "can't set CQL query";
  80     } elsif ($code == ZOOM::Error::QUERY_PQF) {
  81         return "can't set prefix query";
  82     } elsif ($code == ZOOM::Error::SORTBY) {
  83         return "can't set sort-specification";
  84     } elsif ($code == ZOOM::Error::CLONE) {
  85         return "can't clone record";
  86     } elsif ($code == ZOOM::Error::PACKAGE) {
  87         return "can't create package";
  88     } elsif ($code == ZOOM::Error::SCANTERM) {
  89         return "can't retrieve term from scan-set";
  90     } elsif ($code == ZOOM::Error::LOGLEVEL) {
  91         return "unregistered log-level";
  92     }
  93
  94     return Net::Z3950::ZOOM::diag_str($code);
  95 }
  96
  97 sub event_str {
  98     return Net::Z3950::ZOOM::event_str(@_);
  99 }
 100
 101 sub event {
 102     my($connsref) = @_;
 103
 104     my @_connsref = map { $_->_conn() } @$connsref;
 105     return Net::Z3950::ZOOM::event(\@_connsref);
 106 }
 107
 108 sub _oops {
 109     my($code, $addinfo, $diagset) = @_;
 110
 111     die new ZOOM::Exception($code, diag_str($code), $addinfo, $diagset);
 112 }
 113
 114 # ----------------------------------------------------------------------------
 115
 116 package ZOOM::Exception;
 117
 118 sub new {
 119     my $class = shift();
 120     my($code, $message, $addinfo, $diagset) = @_;
 121
 122     return bless {
 123         code => $code,
 124         message => $message,
 125         addinfo => $addinfo,
 126         diagset => $diagset || "ZOOM",
 127     }, $class;
 128 }
 129
 130 sub code {
 131     my $this = shift();
 132     return $this->{code};
 133 }
 134
 135 sub message {
 136     my $this = shift();
 137     return $this->{message};
 138 }
 139
 140 sub addinfo {
 141     my $this = shift();
 142     return $this->{addinfo};
 143 }
 144
 145 sub diagset {
 146     my $this = shift();
 147     return $this->{diagset};
 148 }
 149
 150 sub render {
 151     my $this = shift();
 152     my $res = "ZOOM error " . $this->code() . ' "' . $this->message() . '"';
 153     $res .= ' (addinfo: "' . $this->addinfo() . '")' if $this->addinfo();
 154     $res .= " from diag-set '" . $this->diagset() . "'" if $this->diagset();
 155     return $res;
 156 }
 157
 158 # This means that untrapped exceptions render nicely.
 159 use overload '""' => \&render;
 160
 161 # ----------------------------------------------------------------------------
 162
 163 package ZOOM::Options;
 164
 165 sub new {
 166     my $class = shift();
 167     my($p1, $p2) = @_;
 168
 169     my $opts;
 170     if (@_ == 0) {
 171         $opts = Net::Z3950::ZOOM::options_create();
 172     } elsif (@_ == 1) {
 173         $opts = Net::Z3950::ZOOM::options_create_with_parent($p1->_opts());
 174     } elsif (@_ == 2) {
 175         $opts = Net::Z3950::ZOOM::options_create_with_parent2($p1->_opts(),
 176                                                               $p2->_opts());
 177     } else {
 178         die "can't make $class object with more than 2 parents";
 179     }
 180
 181     return bless {
 182         _opts => $opts,
 183     }, $class;
 184 }
 185
 186 # PRIVATE to this class and ZOOM::Connection::create() and
 187 # ZOOM::Connection::package()
 188 #
 189 sub _opts {
 190     my $this = shift();
 191
 192     my $_opts = $this->{_opts};
 193     die "{_opts} undefined: has this Options block been destroy()ed?"
 194         if !defined $_opts;
 195
 196     return $_opts;
 197 }
 198
 199 sub option {
 200     my $this = shift();
 201     my($key, $value) = @_;
 202
 203     my $oldval = Net::Z3950::ZOOM::options_get($this->_opts(), $key);
 204     Net::Z3950::ZOOM::options_set($this->_opts(), $key, $value)
 205         if defined $value;
 206
 207     return $oldval;
 208 }
 209
 210 sub option_binary {
 211     my $this = shift();
 212     my($key, $value) = @_;
 213
 214     my $dummylen = 0;
 215     my $oldval = Net::Z3950::ZOOM::options_getl($this->_opts(),
 216                                                 $key, $dummylen);
 217     Net::Z3950::ZOOM::options_setl($this->_opts(), $key,
 218                                    $value, length($value))
 219         if defined $value;
 220
 221     return $oldval;
 222 }
 223
 224 # This is a bit stupid, since the scalar values that Perl returns from
 225 # option() can be used as a boolean; but it's just possible that some
 226 # applications will rely on ZOOM_options_get_bool()'s idiosyncratic
 227 # interpretation of what constitutes truth.
 228 #
 229 sub bool {
 230     my $this = shift();
 231     my($key, $default) = @_;
 232
 233     return Net::Z3950::ZOOM::options_get_bool($this->_opts(), $key, $default);
 234 }
 235
 236 # .. and the next two are even more stupid
 237 sub int {
 238     my $this = shift();
 239     my($key, $default) = @_;
 240
 241     return Net::Z3950::ZOOM::options_get_int($this->_opts(), $key, $default);
 242 }
 243
 244 sub set_int {
 245     my $this = shift();
 246     my($key, $value) = @_;
 247
 248     Net::Z3950::ZOOM::options_set_int($this->_opts(), $key, $value);
 249 }
 250
 251 #   ### Feel guilty.  Feel very, very guilty.  I've not been able to
 252 #       get the callback memory-management right in "ZOOM.xs", with
 253 #       the result that the values of $function and $udata passed into
 254 #       this function, which are on the stack, have sometimes been
 255 #       freed by the time they're used by __ZOOM_option_callback(),
 256 #       with hilarious results.  To avoid this, I copy the values into
 257 #       module-scoped globals, and pass _those_ into the extension
 258 #       function.  To avoid overwriting those globals by subsequent
 259 #       calls, I keep all the old ones, pushed onto the @_function and
 260 #       @_udata arrays, which means that THIS FUNCTION LEAKS MEMORY
 261 #       LIKE IT'S GOING OUT OF FASHION.  Not nice.  One day, I should
 262 #       fix this, but for now there's more important fish to fry.
 263 #
 264 my(@_function, @_udata);
 265 sub set_callback {
 266     my $o1 = shift();
 267     my($function, $udata) = @_;
 268
 269     push @_function, $function;
 270     push @_udata, $udata;
 271     Net::Z3950::ZOOM::options_set_callback($o1->_opts(),
 272                                            $_function[-1], $_udata[-1]);
 273 }
 274
 275 sub destroy {
 276     my $this = shift();
 277
 278     Net::Z3950::ZOOM::options_destroy($this->_opts());
 279     $this->{_opts} = undef;
 280 }
 281
 282
 283 # ----------------------------------------------------------------------------
 284
 285 package ZOOM::Connection;
 286
 287 sub new {
 288     my $class = shift();
 289     my($host, $port, @options) = @_;
 290
 291     my $_opts = Net::Z3950::ZOOM::options_create();
 292     while (@options >= 2) {
 293         my $key = shift(@options);
 294         my $val = shift(@options);
 295         Net::Z3950::ZOOM::options_set($_opts, $key, $val);
 296     }
 297
 298     die "Odd number of options specified"
 299         if @options;
 300
 301     my $_conn = Net::Z3950::ZOOM::connection_create($_opts);
 302     Net::Z3950::ZOOM::connection_connect($_conn, $host, $port || 0);
 303     my $conn = bless {
 304         host => $host,
 305         port => $port,
 306         _conn => $_conn,
 307     };
 308
 309     $conn->_check();
 310     return $conn;
 311 }
 312
 313 # PRIVATE to this class, to ZOOM::event() and to ZOOM::Query::CQL2RPN::new()
 314 sub _conn {
 315     my $this = shift();
 316
 317     my $_conn = $this->{_conn};
 318     die "{_conn} undefined: has this Connection been destroy()ed?"
 319         if !defined $_conn;
 320
 321     return $_conn;
 322 }
 323
 324 sub _check {
 325     my $this = shift();
 326
 327     my($errcode, $errmsg, $addinfo, $diagset) = (undef, "x", "x", "x");
 328     $errcode = Net::Z3950::ZOOM::connection_error_x($this->_conn(), $errmsg,
 329                                                     $addinfo, $diagset);
 330     die new ZOOM::Exception($errcode, $errmsg, $addinfo, $diagset)
 331         if $errcode;
 332 }
 333
 334 sub create {
 335     my $class = shift();
 336     my($options) = @_;
 337
 338     my $_conn = Net::Z3950::ZOOM::connection_create($options->_opts());
 339     return bless {
 340         host => undef,
 341         port => undef,
 342         _conn => $_conn,
 343     };
 344 }
 345
 346 sub error_x {
 347     my $this = shift();
 348
 349     my($errcode, $errmsg, $addinfo, $diagset) = (undef, "dummy", "dummy", "d");
 350     $errcode = Net::Z3950::ZOOM::connection_error_x($this->_conn(), $errmsg,
 351                                                     $addinfo, $diagset);
 352     return ($errcode, $errmsg, $addinfo, $diagset);
 353 }
 354
 355 sub errcode {
 356     my $this = shift();
 357     return Net::Z3950::ZOOM::connection_errcode($this->_conn());
 358 }
 359
 360 sub errmsg {
 361     my $this = shift();
 362     return Net::Z3950::ZOOM::connection_errmsg($this->_conn());
 363 }
 364
 365 sub addinfo {
 366     my $this = shift();
 367     return Net::Z3950::ZOOM::connection_addinfo($this->_conn());
 368 }
 369
 370 sub diagset {
 371     my $this = shift();
 372     return Net::Z3950::ZOOM::connection_diagset($this->_conn());
 373 }
 374
 375 sub connect {
 376     my $this = shift();
 377     my($host, $port) = @_;
 378
 379     $port = 0 if !defined $port;
 380     Net::Z3950::ZOOM::connection_connect($this->_conn(), $host, $port);
 381     $this->_check();
 382     # No return value
 383 }
 384
 385 sub option {
 386     my $this = shift();
 387     my($key, $value) = @_;
 388
 389     my $oldval = Net::Z3950::ZOOM::connection_option_get($this->_conn(), $key);
 390     Net::Z3950::ZOOM::connection_option_set($this->_conn(), $key, $value)
 391         if defined $value;
 392
 393     return $oldval;
 394 }
 395
 396 sub option_binary {
 397     my $this = shift();
 398     my($key, $value) = @_;
 399
 400     my $dummylen = 0;
 401     my $oldval = Net::Z3950::ZOOM::connection_option_getl($this->_conn(),
 402                                                           $key, $dummylen);
 403     Net::Z3950::ZOOM::connection_option_setl($this->_conn(), $key,
 404                                              $value, length($value))
 405         if defined $value;
 406
 407     return $oldval;
 408 }
 409
 410 sub search {
 411     my $this = shift();
 412     my($query) = @_;
 413
 414     my $_rs = Net::Z3950::ZOOM::connection_search($this->_conn(),
 415                                                   $query->_query());
 416     $this->_check();
 417     return _new ZOOM::ResultSet($this, $query, $_rs);
 418 }
 419
 420 sub search_pqf {
 421     my $this = shift();
 422     my($pqf) = @_;
 423
 424     my $_rs = Net::Z3950::ZOOM::connection_search_pqf($this->_conn(), $pqf);
 425     $this->_check();
 426     return _new ZOOM::ResultSet($this, $pqf, $_rs);
 427 }
 428
 429 sub scan_pqf {
 430     my $this = shift();
 431     my($startterm) = @_;
 432
 433     my $_ss = Net::Z3950::ZOOM::connection_scan($this->_conn(), $startterm);
 434     $this->_check();
 435     return _new ZOOM::ScanSet($this, $startterm, $_ss);
 436 }
 437
 438 sub scan {
 439     my $this = shift();
 440     my($query) = @_;
 441
 442     my $_ss = Net::Z3950::ZOOM::connection_scan1($this->_conn(),
 443                                                  $query->_query());
 444     $this->_check();
 445     return _new ZOOM::ScanSet($this, $query, $_ss);
 446 }
 447
 448 sub package {
 449     my $this = shift();
 450     my($options) = @_;
 451
 452     my $_o = defined $options ? $options->_opts() :
 453         Net::Z3950::ZOOM::options_create();
 454     my $_p = Net::Z3950::ZOOM::connection_package($this->_conn(), $_o)
 455         or ZOOM::_oops(ZOOM::Error::PACKAGE);
 456
 457     return _new ZOOM::Package($this, $options, $_p);
 458 }
 459
 460 sub last_event {
 461     my $this = shift();
 462
 463     return Net::Z3950::ZOOM::connection_last_event($this->_conn());
 464 }
 465
 466 sub destroy {
 467     my $this = shift();
 468
 469     Net::Z3950::ZOOM::connection_destroy($this->_conn());
 470     $this->{_conn} = undef;
 471 }
 472
 473
 474 # ----------------------------------------------------------------------------
 475
 476 package ZOOM::Query;
 477
 478 sub new {
 479     my $class = shift();
 480     die "You can't create $class objects: it's a virtual base class";
 481 }
 482
 483 # PRIVATE to this class and ZOOM::Connection::search()
 484 sub _query {
 485     my $this = shift();
 486
 487     my $_query = $this->{_query};
 488     die "{_query} undefined: has this Query been destroy()ed?"
 489         if !defined $_query;
 490
 491     return $_query;
 492 }
 493
 494 sub sortby {
 495     my $this = shift();
 496     my($sortby) = @_;
 497
 498     Net::Z3950::ZOOM::query_sortby($this->_query(), $sortby) == 0
 499         or ZOOM::_oops(ZOOM::Error::SORTBY, $sortby);
 500 }
 501
 502 sub destroy {
 503     my $this = shift();
 504
 505     Net::Z3950::ZOOM::query_destroy($this->_query());
 506     $this->{_query} = undef;
 507 }
 508
 509
 510 package ZOOM::Query::CQL;
 511 our @ISA = qw(ZOOM::Query);
 512
 513 sub new {
 514     my $class = shift();
 515     my($string) = @_;
 516
 517     my $q = Net::Z3950::ZOOM::query_create()
 518         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 519     Net::Z3950::ZOOM::query_cql($q, $string) == 0
 520         or ZOOM::_oops(ZOOM::Error::QUERY_CQL, $string);
 521
 522     return bless {
 523         _query => $q,
 524     }, $class;
 525 }
 526
 527
 528 package ZOOM::Query::CQL2RPN;
 529 our @ISA = qw(ZOOM::Query);
 530
 531 sub new {
 532     my $class = shift();
 533     my($string, $conn) = @_;
 534
 535     my $q = Net::Z3950::ZOOM::query_create()
 536         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 537     # check() throws the exception we want; but we only want it on failure!
 538     Net::Z3950::ZOOM::query_cql2rpn($q, $string, $conn->_conn()) == 0
 539         or $conn->_check();
 540
 541     return bless {
 542         _query => $q,
 543     }, $class;
 544 }
 545
 546
 547 package ZOOM::Query::PQF;
 548 our @ISA = qw(ZOOM::Query);
 549
 550 sub new {
 551     my $class = shift();
 552     my($string) = @_;
 553
 554     my $q = Net::Z3950::ZOOM::query_create()
 555         or ZOOM::_oops(ZOOM::Error::CREATE_QUERY);
 556     Net::Z3950::ZOOM::query_prefix($q, $string) == 0
 557         or ZOOM::_oops(ZOOM::Error::QUERY_PQF, $string);
 558
 559     return bless {
 560         _query => $q,
 561     }, $class;
 562 }
 563
 564
 565 # ----------------------------------------------------------------------------
 566
 567 package ZOOM::ResultSet;
 568
 569 sub new {
 570     my $class = shift();
 571     die "You can't create $class objects directly";
 572 }
 573
 574 # PRIVATE to ZOOM::Connection::search() and ZOOM::Connection::search_pqf()
 575 sub _new {
 576     my $class = shift();
 577     my($conn, $query, $_rs) = @_;
 578
 579     return bless {
 580         conn => $conn,
 581         query => $query,        # This is not currently used, which is
 582                                 # just as well since it could be
 583                                 # either a string (when the RS is
 584                                 # created with search_pqf()) or a
 585                                 # ZOOM::Query object (when it's
 586                                 # created with search())
 587         _rs => $_rs,
 588     }, $class;
 589 }
 590
 591 # PRIVATE to this class
 592 sub _rs {
 593     my $this = shift();
 594
 595     my $_rs = $this->{_rs};
 596     die "{_rs} undefined: has this ResultSet been destroy()ed?"
 597         if !defined $_rs;
 598
 599     return $_rs;
 600 }
 601
 602 sub option {
 603     my $this = shift();
 604     my($key, $value) = @_;
 605
 606     my $oldval = Net::Z3950::ZOOM::resultset_option_get($this->_rs(), $key);
 607     Net::Z3950::ZOOM::resultset_option_set($this->_rs(), $key, $value)
 608         if defined $value;
 609
 610     return $oldval;
 611 }
 612
 613 sub size {
 614     my $this = shift();
 615
 616     return Net::Z3950::ZOOM::resultset_size($this->_rs());
 617 }
 618
 619 sub record {
 620     my $this = shift();
 621     my($which) = @_;
 622
 623     my $_rec = Net::Z3950::ZOOM::resultset_record($this->_rs(), $which);
 624     $this->{conn}->_check();
 625
 626     # Even if no error has occurred, I think record() might
 627     # legitimately return undef if we're running in asynchronous mode
 628     # and the record just hasn't been retrieved yet.  This goes double
 629     # for record_immediate().
 630     return undef if !defined $_rec;
 631
 632     # For some reason, I have to use the explicit "->" syntax in order
 633     # to invoke the ZOOM::Record constructor here, even though I don't
 634     # have to do the same for _new ZOOM::ResultSet above.  Weird.
 635     return ZOOM::Record->_new($this, $which, $_rec);
 636 }
 637
 638 sub record_immediate {
 639     my $this = shift();
 640     my($which) = @_;
 641
 642     my $_rec = Net::Z3950::ZOOM::resultset_record_immediate($this->_rs(),
 643                                                             $which);
 644     $this->{conn}->_check();
 645     # The record might legitimately not be there yet
 646     return undef if !defined $_rec;
 647
 648     return ZOOM::Record->_new($this, $which, $_rec);
 649 }
 650
 651 sub cache_reset {
 652     my $this = shift();
 653
 654     Net::Z3950::ZOOM::resultset_cache_reset($this->_rs());
 655 }
 656
 657 sub records {
 658     my $this = shift();
 659     my($start, $count, $return_records) = @_;
 660
 661     my $raw = Net::Z3950::ZOOM::resultset_records($this->_rs(), $start, $count,
 662                                                   $return_records);
 663     # By design, $raw may be undefined (if $return_records is true)
 664     return undef if !defined $raw;
 665
 666     # We need to package up the returned records in ZOOM::Record objects
 667     my @res = ();
 668     for my $i (0 .. @$raw-1) {
 669         my $_rec = $raw->[$i];
 670         if (!defined $_rec) {
 671             push @res, undef;
 672         } else {
 673             push @res, ZOOM::Record->_new($this, $start+$i, $_rec);
 674         }
 675     }
 676
 677     return \@res;
 678 }
 679
 680 sub sort {
 681     my $this = shift();
 682     my($sort_type, $sort_spec) = @_;
 683
 684     return Net::Z3950::ZOOM::resultset_sort1($this->_rs(),
 685                                              $sort_type, $sort_spec);
 686 }
 687
 688 sub destroy {
 689     my $this = shift();
 690
 691     Net::Z3950::ZOOM::resultset_destroy($this->_rs());
 692     $this->{_rs} = undef;
 693 }
 694
 695
 696 # ----------------------------------------------------------------------------
 697
 698 package ZOOM::Record;
 699
 700 sub new {
 701     my $class = shift();
 702     die "You can't create $class objects directly";
 703 }
 704
 705 # PRIVATE to ZOOM::ResultSet::record(),
 706 # ZOOM::ResultSet::record_immediate(), ZOOM::ResultSet::records() and
 707 # ZOOM::Record::clone()
 708 #
 709 sub _new {
 710     my $class = shift();
 711     my($rs, $which, $_rec) = @_;
 712
 713     return bless {
 714         rs => $rs,
 715         which => $which,
 716         _rec => $_rec,
 717     }, $class;
 718 }
 719
 720 # PRIVATE to this class
 721 sub _rec {
 722     my $this = shift();
 723
 724     my $_rec = $this->{_rec};
 725     die "{_rec} undefined: has this Record been destroy()ed?"
 726         if !defined $_rec;
 727
 728     return $_rec;
 729 }
 730
 731 sub render {
 732     my $this = shift();
 733
 734     return $this->get("render", @_);
 735 }
 736
 737 sub raw {
 738     my $this = shift();
 739
 740     return $this->get("raw", @_);
 741 }
 742
 743 sub get {
 744     my $this = shift();
 745     my($type, $args) = @_;
 746
 747     $type = "$type;$args" if defined $args;
 748     my $len = 0;
 749     my $string = Net::Z3950::ZOOM::record_get($this->_rec(), $type, $len);
 750     # I don't think we need '$len' at all.  ### Probably the Perl-to-C
 751     # glue code should use the value of `len' as well as the opaque
 752     # data-pointer returned, to ensure that the SV contains all of the
 753     # returned data and does not stop at the first NUL character in
 754     # binary data.  Carefully check the ZOOM_record_get() documentation.
 755     return $string;
 756 }
 757
 758 sub clone {
 759     my $this = shift();
 760
 761     my $raw = Net::Z3950::ZOOM::record_clone($this->_rec())
 762         or ZOOM::_oops(ZOOM::Error::CLONE);
 763
 764     # Arg 1 (rs) is undefined as the new record doesn't belong to an RS
 765     return _new ZOOM::Record(undef, undef, $raw);
 766 }
 767
 768 sub destroy {
 769     my $this = shift();
 770
 771     Net::Z3950::ZOOM::record_destroy($this->_rec());
 772     $this->{_rec} = undef;
 773 }
 774
 775
 776 # ----------------------------------------------------------------------------
 777
 778 package ZOOM::ScanSet;
 779
 780 sub new {
 781     my $class = shift();
 782     die "You can't create $class objects directly";
 783 }
 784
 785 # PRIVATE to ZOOM::Connection::scan(),
 786 sub _new {
 787     my $class = shift();
 788     my($conn, $startterm, $_ss) = @_;
 789
 790     return bless {
 791         conn => $conn,
 792         startterm => $startterm,# This is not currently used, which is
 793                                 # just as well since it could be
 794                                 # either a string (when the SS is
 795                                 # created with scan()) or a
 796                                 # ZOOM::Query object (when it's
 797                                 # created with scan1())
 798         _ss => $_ss,
 799     }, $class;
 800 }
 801
 802 # PRIVATE to this class
 803 sub _ss {
 804     my $this = shift();
 805
 806     my $_ss = $this->{_ss};
 807     die "{_ss} undefined: has this ScanSet been destroy()ed?"
 808         if !defined $_ss;
 809
 810     return $_ss;
 811 }
 812
 813 sub option {
 814     my $this = shift();
 815     my($key, $value) = @_;
 816
 817     my $oldval = Net::Z3950::ZOOM::scanset_option_get($this->_ss(), $key);
 818     Net::Z3950::ZOOM::scanset_option_set($this->_ss(), $key, $value)
 819         if defined $value;
 820
 821     return $oldval;
 822 }
 823
 824 sub size {
 825     my $this = shift();
 826
 827     return Net::Z3950::ZOOM::scanset_size($this->_ss());
 828 }
 829
 830 sub term {
 831     my $this = shift();
 832     my($which) = @_;
 833
 834     my($occ, $len) = (0, 0);
 835     my $term = Net::Z3950::ZOOM::scanset_term($this->_ss(), $which,
 836                                               $occ, $len)
 837         or ZOOM::_oops(ZOOM::Error::SCANTERM);
 838
 839     die "length of term '$term' differs from returned len=$len"
 840         if length($term) != $len;
 841
 842     return ($term, $occ);
 843 }
 844
 845 sub display_term {
 846     my $this = shift();
 847     my($which) = @_;
 848
 849     my($occ, $len) = (0, 0);
 850     my $term = Net::Z3950::ZOOM::scanset_display_term($this->_ss(), $which,
 851                                                       $occ, $len)
 852         or ZOOM::_oops(ZOOM::Error::SCANTERM);
 853
 854     die "length of display term '$term' differs from returned len=$len"
 855         if length($term) != $len;
 856
 857     return ($term, $occ);
 858 }
 859
 860 sub destroy {
 861     my $this = shift();
 862
 863     Net::Z3950::ZOOM::scanset_destroy($this->_ss());
 864     $this->{_ss} = undef;
 865 }
 866
 867
 868 # ----------------------------------------------------------------------------
 869
 870 package ZOOM::Package;
 871
 872 sub new {
 873     my $class = shift();
 874     die "You can't create $class objects directly";
 875 }
 876
 877 # PRIVATE to ZOOM::Connection::package(),
 878 sub _new {
 879     my $class = shift();
 880     my($conn, $options, $_p) = @_;
 881
 882     return bless {
 883         conn => $conn,
 884         options => $options,
 885         _p => $_p,
 886     }, $class;
 887 }
 888
 889 # PRIVATE to this class
 890 sub _p {
 891     my $this = shift();
 892
 893     my $_p = $this->{_p};
 894     die "{_p} undefined: has this Package been destroy()ed?"
 895         if !defined $_p;
 896
 897     return $_p;
 898 }
 899
 900 sub option {
 901     my $this = shift();
 902     my($key, $value) = @_;
 903
 904     my $oldval = Net::Z3950::ZOOM::package_option_get($this->_p(), $key);
 905     Net::Z3950::ZOOM::package_option_set($this->_p(), $key, $value)
 906         if defined $value;
 907
 908     return $oldval;
 909 }
 910
 911 sub send {
 912     my $this = shift();
 913     my($type) = @_;
 914
 915     Net::Z3950::ZOOM::package_send($this->_p(), $type);
 916     $this->{conn}->_check();
 917 }
 918
 919 sub destroy {
 920     my $this = shift();
 921
 922     Net::Z3950::ZOOM::package_destroy($this->_p());
 923     $this->{_p} = undef;
 924 }
 925
 926
 927 # There follows trivial support for YAZ logging.  This is wired out
 928 # into the Net::Z3950::ZOOM package, and we here provide wrapper
 929 # functions -- nothing more than aliases, really -- in the ZOOM::Log
 930 # package.  There really is no point in inventing an OO interface.
 931 #
 932 # Passing @_ directly to the underlying Net::Z3950::ZOOM::* functions
 933 # doesn't work, for reasons that I can't begin to fathom, and that
 934 # don't particularly interest me.  Unpacking into scalars and passing
 935 # those _does_ work, so that's what we do.
 936
 937 package ZOOM::Log;
 938
 939 sub mask_str      { my($a) = @_; Net::Z3950::ZOOM::yaz_log_mask_str($a); }
 940 sub module_level  { my($a) = @_; Net::Z3950::ZOOM::yaz_log_module_level($a); }
 941 sub init          { my($a, $b, $c) = @_;
 942                     Net::Z3950::ZOOM::yaz_log_init($a, $b, $c) }
 943 sub init_file     { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_file($a) }
 944 sub init_level    { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_level($a) }
 945 sub init_prefix   { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_prefix($a) }
 946 sub time_format   { my($a) = @_; Net::Z3950::ZOOM::yaz_log_time_format($a) }
 947 sub init_max_size { my($a) = @_; Net::Z3950::ZOOM::yaz_log_init_max_size($a) }
 948
 949 sub log {
 950     my($level, @message) = @_;
 951
 952     if ($level !~ /^(0x)?\d+$/) {
 953         # Assuming its log-level name, we look it up.
 954         my $num = module_level($level);
 955         ZOOM::_oops(ZOOM::Error::LOGLEVEL, $level)
 956             if $num == 0;
 957         $level = $num;
 958     }
 959
 960     Net::Z3950::ZOOM::yaz_log($level, join("", @message));
 961 }
 962
 963
 964 1;