# $Id: Pod.pm,v 1.3 2006-05-09 16:31:05 mike Exp $

package ZOOM::Pod;

use strict;
use warnings;

use ZOOM;

=head1 SYNOPSIS

 use ZOOM::Pod;

 $pod = new ZOOM::Pod("bagel.indexdata.com/gils",
                      "bagel.indexdata.com/marc");
 $pod->callback(ZOOM::Event::RECV_SEARCH, \&completed_search);
 $pod->callback(ZOOM::Event::RECV_RECORD, \&got_record);
 $pod->search_pqf("the");
 $err = $pod->wait();
 die "$pod->wait() failed with error $err" if $err;

 sub completed_search {
     ($conn, $rs) = @_;
     print $conn->option("host"), ": found ", $rs->size(), " records\n";
     $rs->record(0); # Queues a request for the record
     return 0;
 }

 sub got_record {
     ($conn, $rs) = @_;
     $rec = $rs->record(0);
     print $conn->option("host"), ": got $rec = '", $rec->render(), "'\n";
     return 0;
 }

=cut

BEGIN {
    # Just register the name
    ZOOM::Log::mask_str("pod");
}

sub new {
    my $class = shift();
    my(@conn) = @_;

    my @state; # Hashrefs with application state associated with connections
    foreach my $conn (@conn) {
	if (!ref $conn) {
	    $conn = new ZOOM::Connection($conn, 0, async => 1);
	}
	push @state, {};
    }

    return bless {
	conn => \@conn,
	state => \@state,
	rs => [],
	callback => {},
    }, $class;
}

sub option {
    my $this = shift();
    my($key, $value) = @_;

    foreach my $conn (@{ $this->{conn} }) {
	$conn->option($key, $value);
    }
}

sub callback {
    my $this = shift();
    my($event, $sub) = @_;

    my $old = $this->{callback}->{$event};
    $this->{callback}->{$event} = $sub
	if defined $sub;

    return $old;
}

sub search_pqf {
    my $this = shift();
    my($pqf) = @_;

    foreach my $i (0..@{ $this->{conn} }-1) {
	$this->{rs}->[$i] = $this->{conn}->[$i]->search_pqf($pqf);
    }
}

sub wait {
    my $this = shift();
    my $res = 0;

    while ((my $i = ZOOM::event($this->{conn})) != 0) {
	my $conn = $this->{conn}->[$i-1];
	my $ev = $conn->last_event();
	ZOOM::Log::log("pod", "connection ", $i-1, ": ", ZOOM::event_str($ev));
	my $sub = $this->{callback}->{$ev};
	if (defined $sub) {
	    $res = &$sub($conn, $this->{state}->[$i-1],
			 $this->{rs}->[$i-1], $ev);
	    last if $res != 0;
	}
    }

    return $res;
}


1;
